mirror of
https://github.com/explosion/spaCy.git
synced 2024-11-14 21:57:15 +03:00
78a8bec4d0
* Make core projectivization methods cdef nogil While profiling the parser, I noticed that relatively a lot of time is spent in projectivization. This change rewrites the functions in the core loops as cdef nogil for efficiency. In C++-land, we use vector in place of Python lists and absent heads are represented as -1 in place of None. * _heads_to_c: add assertion Validation should be performed by the caller, but this assertion ensures that we are not reading/writing out of bounds with incorrect input.
226 lines
7.4 KiB
Cython
226 lines
7.4 KiB
Cython
# cython: profile=True, infer_types=True
|
|
"""Implements the projectivize/deprojectivize mechanism in Nivre & Nilsson 2005
|
|
for doing pseudo-projective parsing implementation uses the HEAD decoration
|
|
scheme.
|
|
"""
|
|
from copy import copy
|
|
from libc.limits cimport INT_MAX
|
|
from libc.stdlib cimport abs
|
|
from libcpp cimport bool
|
|
from libcpp.vector cimport vector
|
|
|
|
from ...tokens.doc cimport Doc, set_children_from_heads
|
|
|
|
from ...errors import Errors
|
|
|
|
|
|
DELIMITER = '||'
|
|
|
|
|
|
def ancestors(tokenid, heads):
|
|
# Returns all words going from the word up the path to the root. The path
|
|
# to root cannot be longer than the number of words in the sentence. This
|
|
# function ends after at most len(heads) steps, because it would otherwise
|
|
# loop indefinitely on cycles.
|
|
head = tokenid
|
|
cnt = 0
|
|
while heads[head] != head and cnt < len(heads):
|
|
head = heads[head]
|
|
cnt += 1
|
|
yield head
|
|
if head is None:
|
|
break
|
|
|
|
|
|
def contains_cycle(heads):
|
|
# in an acyclic tree, the path from each word following the head relation
|
|
# upwards always ends at the root node
|
|
for tokenid in range(len(heads)):
|
|
seen = set([tokenid])
|
|
for ancestor in ancestors(tokenid, heads):
|
|
if ancestor in seen:
|
|
return seen
|
|
seen.add(ancestor)
|
|
return None
|
|
|
|
|
|
def is_nonproj_arc(tokenid, heads):
|
|
cdef vector[int] c_heads = _heads_to_c(heads)
|
|
return _is_nonproj_arc(tokenid, c_heads)
|
|
|
|
|
|
cdef bool _is_nonproj_arc(int tokenid, const vector[int]& heads) nogil:
|
|
# definition (e.g. Havelka 2007): an arc h -> d, h < d is non-projective
|
|
# if there is a token k, h < k < d such that h is not
|
|
# an ancestor of k. Same for h -> d, h > d
|
|
head = heads[tokenid]
|
|
if head == tokenid: # root arcs cannot be non-projective
|
|
return False
|
|
elif head < 0: # unattached tokens cannot be non-projective
|
|
return False
|
|
|
|
cdef int start, end
|
|
if head < tokenid:
|
|
start, end = (head+1, tokenid)
|
|
else:
|
|
start, end = (tokenid+1, head)
|
|
for k in range(start, end):
|
|
if _has_head_as_ancestor(k, head, heads):
|
|
continue
|
|
else: # head not in ancestors: d -> h is non-projective
|
|
return True
|
|
return False
|
|
|
|
|
|
cdef bool _has_head_as_ancestor(int tokenid, int head, const vector[int]& heads) nogil:
|
|
ancestor = tokenid
|
|
cnt = 0
|
|
while cnt < heads.size():
|
|
if heads[ancestor] == head or heads[ancestor] < 0:
|
|
return True
|
|
ancestor = heads[ancestor]
|
|
cnt += 1
|
|
|
|
return False
|
|
|
|
|
|
def is_nonproj_tree(heads):
|
|
cdef vector[int] c_heads = _heads_to_c(heads)
|
|
# a tree is non-projective if at least one arc is non-projective
|
|
return any(_is_nonproj_arc(word, c_heads) for word in range(len(heads)))
|
|
|
|
|
|
def decompose(label):
|
|
return label.partition(DELIMITER)[::2]
|
|
|
|
|
|
def is_decorated(label):
|
|
return DELIMITER in label
|
|
|
|
def count_decorated_labels(gold_data):
|
|
freqs = {}
|
|
for example in gold_data:
|
|
proj_heads, deco_deps = projectivize(example.get_aligned("HEAD"),
|
|
example.get_aligned("DEP"))
|
|
# set the label to ROOT for each root dependent
|
|
deco_deps = ['ROOT' if head == i else deco_deps[i]
|
|
for i, head in enumerate(proj_heads)]
|
|
# count label frequencies
|
|
for label in deco_deps:
|
|
if is_decorated(label):
|
|
freqs[label] = freqs.get(label, 0) + 1
|
|
return freqs
|
|
|
|
|
|
def projectivize(heads, labels):
|
|
# Use the algorithm by Nivre & Nilsson 2005. Assumes heads to be a proper
|
|
# tree, i.e. connected and cycle-free. Returns a new pair (heads, labels)
|
|
# which encode a projective and decorated tree.
|
|
proj_heads = copy(heads)
|
|
|
|
cdef int new_head
|
|
cdef vector[int] c_proj_heads = _heads_to_c(proj_heads)
|
|
cdef int smallest_np_arc = _get_smallest_nonproj_arc(c_proj_heads)
|
|
if smallest_np_arc == -1: # this sentence is already projective
|
|
return proj_heads, copy(labels)
|
|
while smallest_np_arc != -1:
|
|
new_head = _lift(smallest_np_arc, proj_heads)
|
|
c_proj_heads[smallest_np_arc] = new_head
|
|
smallest_np_arc = _get_smallest_nonproj_arc(c_proj_heads)
|
|
deco_labels = _decorate(heads, proj_heads, labels)
|
|
return proj_heads, deco_labels
|
|
|
|
|
|
cdef vector[int] _heads_to_c(heads):
|
|
cdef vector[int] c_heads;
|
|
for head in heads:
|
|
if head == None:
|
|
c_heads.push_back(-1)
|
|
else:
|
|
assert head < len(heads)
|
|
c_heads.push_back(head)
|
|
return c_heads
|
|
|
|
|
|
cpdef deprojectivize(Doc doc):
|
|
# Reattach arcs with decorated labels (following HEAD scheme). For each
|
|
# decorated arc X||Y, search top-down, left-to-right, breadth-first until
|
|
# hitting a Y then make this the new head.
|
|
for i in range(doc.length):
|
|
label = doc.vocab.strings[doc.c[i].dep]
|
|
if DELIMITER in label:
|
|
new_label, head_label = label.split(DELIMITER)
|
|
new_head = _find_new_head(doc[i], head_label)
|
|
doc.c[i].head = new_head.i - i
|
|
doc.c[i].dep = doc.vocab.strings.add(new_label)
|
|
set_children_from_heads(doc.c, 0, doc.length)
|
|
return doc
|
|
|
|
|
|
def _decorate(heads, proj_heads, labels):
|
|
# uses decoration scheme HEAD from Nivre & Nilsson 2005
|
|
if (len(heads) != len(proj_heads)) or (len(proj_heads) != len(labels)):
|
|
raise ValueError(Errors.E082.format(n_heads=len(heads),
|
|
n_proj_heads=len(proj_heads),
|
|
n_labels=len(labels)))
|
|
deco_labels = []
|
|
for tokenid, head in enumerate(heads):
|
|
if head != proj_heads[tokenid]:
|
|
deco_labels.append(f"{labels[tokenid]}{DELIMITER}{labels[head]}")
|
|
else:
|
|
deco_labels.append(labels[tokenid])
|
|
return deco_labels
|
|
|
|
def get_smallest_nonproj_arc_slow(heads):
|
|
cdef vector[int] c_heads = _heads_to_c(heads)
|
|
return _get_smallest_nonproj_arc(c_heads)
|
|
|
|
|
|
cdef int _get_smallest_nonproj_arc(const vector[int]& heads) nogil:
|
|
# return the smallest non-proj arc or None
|
|
# where size is defined as the distance between dep and head
|
|
# and ties are broken left to right
|
|
cdef int smallest_size = INT_MAX
|
|
cdef int smallest_np_arc = -1
|
|
cdef int size
|
|
cdef int tokenid
|
|
cdef int head
|
|
|
|
for tokenid in range(heads.size()):
|
|
head = heads[tokenid]
|
|
size = abs(tokenid-head)
|
|
if size < smallest_size and _is_nonproj_arc(tokenid, heads):
|
|
smallest_size = size
|
|
smallest_np_arc = tokenid
|
|
return smallest_np_arc
|
|
|
|
|
|
cpdef int _lift(tokenid, heads):
|
|
# reattaches a word to it's grandfather
|
|
head = heads[tokenid]
|
|
ghead = heads[head]
|
|
cdef int new_head = ghead if head != ghead else tokenid
|
|
# attach to ghead if head isn't attached to root else attach to root
|
|
heads[tokenid] = new_head
|
|
return new_head
|
|
|
|
|
|
def _find_new_head(token, headlabel):
|
|
# search through the tree starting from the head of the given token
|
|
# returns the id of the first descendant with the given label
|
|
# if there is none, return the current head (no change)
|
|
queue = [token.head]
|
|
while queue:
|
|
next_queue = []
|
|
for qtoken in queue:
|
|
for child in qtoken.children:
|
|
if child.is_space:
|
|
continue
|
|
if child == token:
|
|
continue
|
|
if child.dep_ == headlabel:
|
|
return child
|
|
next_queue.append(child)
|
|
queue = next_queue
|
|
return token.head
|